/***********************************************************/
/* Appele par drawline pour dessiner un pont plutot qu'une */
/* route						   */
/***********************************************************/
drawpont:
        ldy        #60	// Index pour etre sur la premiere ligne de la zone de jeu

        lda        logique    // initialisation d'un pointeur sur l'ecran logique
        sta        $e8    

        lda        logique+1
        sta        $e9

	ldx	   DrwCptG    // Compteur pour dessiner l'eau a gauche de la route
bcldrawpontG:
        lda        #255
        sta        ($e8),y
	dex	
	iny
	cpx	#0
	bne bcldrawpontG

	lda	level
	cmp	#4
	bne okdessinepont
	lda	cpttroue
	cmp	#0
	beq tstaleapont
	jsr conttrouepont
	jmp dessinhorspont
tstaleapont
	lda	53770
	cmp	#253
	bne okdessinepont
	jsr trouepont
	jmp dessinhorspont
okdessinepont:
// Bordure de gauche, cad limite entre l'herbe et la route
	ldx	pilier
	cpx	#1
	beq colonepont
	cpx	#2
	beq colonepont
	ldx	desPont
	cpx 	#1
	beq colonepont1
	cpx	#2
	beq colonepont
	inx
	cpx	longPont
	beq colonepont
	inx
	cpx	longPont
	beq colonepont

	lda	#%11011001   // dessin de la bordure Gauche
	jmp okDrawpont

colonepont1:

	lda	53770
	cmp	#255
	beq corrlongpont
	cmp	#254
	beq corrlongpont
	sta	longPont
	jmp colonepont

corrlongpont:
	lda	#250
	sta	longPont
	
colonepont:	
	lda	#%01010101

okDrawpont:
	sta	($e8),y
	iny

	lda	#0
	ldx	TailleRoute
EffaceRoutePont:
        sta        ($e8),y
	dex	
	iny
	cpx	#0
	bne EffaceRoutePont

	ldx	pilier
	cpx	#1
	beq colonepontb
	cpx	#2
	beq colonepontb
	ldx	   desPont
	cpx 	#1
	beq colonepontb
	cpx	#2
	beq colonepontb
	inx
	cpx	longPont
	beq colonepontb
	inx	
	cpx 	longPont
	beq colonepontb

	lda	#%01100111 // bordure de droite
	jmp ok1Drawpont

colonepontb:	
	lda	#%01010101

// Bordure de droite // limite entre la route et l'herbe
ok1Drawpont:
	sta	($e8),y
	iny

dessinhorspont:
	ldx	   DrwCptD // Puis dessin de l'eau
bcldrawpontD:
        lda        #255
        sta        ($e8),y
	dex	
	iny
	cpx	#0
	bne bcldrawpontD

	ldx	   desPont // Ou en sommes nous du dessin du pont
	inx
	cpx	longPont
	bne findrawPonta
	ldx	#0	// Fin du dessin du pont

findrawPonta
	stx	desPont
	ldx	pilier
	inx	
	cpx	#10
	bne findrawPontb
	ldx	#0

findrawPontb:
	stx	pilier

	rts

trouepont
	lda	#20
	sta	cpttroue
conttrouepont
	ldx	cpttroue
	dex
	stx	cpttroue

	ldx	TailleRoute
	inx
	inx     // Pour les 2 colonnes
	lda	#255
bcltrouepont
	sta	($e8),y
	dex
	iny
	cpx	#0
	bne bcltrouepont
	rts	
     
cpttroue db 0